Επίλυση Μ.Δ.Ε. με μετασχηματισμούς

Μετασχηματισμός Laplace (μετασχηματίζουμε ως προς τα $x\in(0,+\infty)$)

Στήνουμε τη ΜΔΕ.

Clear["Global`*"]
PDE = D[u[x, t], t] == D[u[x, t], {x, 4}]
bound1 = u[0, t] == 0
bound2 = u[Pi, t] == 0
bound3 = Derivative[1, 0][u][0, t] == Exp[-4 t]
bound4 = Derivative[1, 0][u][Pi, t] == -(Cosh[Pi]) Exp[-4 t]
init = u[x, 0] == Sin[x] Cosh[x]

u^{(0,1)}(x,t)=u^{(4,0)}(x,t)

\[u(0,t)=0\]

u(\pi ,t)=0

u^{(1,0)}(0,t)=E^{-4 t}

u^{(1,0)}(\pi ,t)=-(E^{-4 t}) \cosh(\pi )

u(x,0)=\cosh(x) \sin(x)

Μετασχηματίζουμε

LaplaceTransform[PDE[[1]], t, s]

\(s LaplaceTransform[u(x,t),t,s]-u(x,0)\)

PDEtr = s uTr[x, s] - init[[2]] == D[uTr[x, s], {x, 4}]
bound1Tr = uTr[0, s] == 0
bound2Tr = uTr[Pi, s] == 0
bound3Tr = 
 Derivative[1, 0][uTr][0, s] == LaplaceTransform[Exp[-4 t], t, s]
bound4Tr = 
 Derivative[1, 0][uTr][Pi, s] == LaplaceTransform[-(Cosh[Pi]) Exp[-4 t], t, s]

-\cosh(x) \sin(x)+s uTr(x,s)=uTr^{(4,0)}(x,s)

\[uTr(0,s)=0\]

uTr(\pi ,s)=0

uTr^{(1,0)}(0,s)=\frac{1}{4+s}

uTr^{(1,0)}(\pi ,s)=-\frac{\cosh(\pi )}{4+s}

Λύνουμε τη μετασχηματισμένη εξίσωση.

sol = DSolve[{PDEtr, bound1Tr, bound2Tr, bound3Tr, bound4Tr}, uTr[x, s], x]

sol[[1, 1, 2]] // Simplify

\frac{\cosh(x) \sin(x)}{4+s}

Αντιστρέφουμε τη λύση.

InverseLaplaceTransform[%, s, t]

(E^{-4 t}) \cosh(x) \sin(x)

Μετασχηματισμός Fourier (μετασχηματίζουμε ως προς τα $x\in\mathbb{R}$)

Η ΜΔΕ

Clear["Global`*"]
PDE = D[u[x, t], t] == k D[u[x, t], {x, 2}]
init = u[x, 0] == 1 - HeavisideTheta[x]

u^{(0,1)}(x,t)=k u^{(2,0)}(x,t)

\[u(x,0)=1-HeavisideTheta[x]\]

Μετασχηματίζουμε.

FourierTransform[PDE[[1]], x, w]
FourierTransform[PDE[[2]], x, w]
FourierTransform[init[[2]], x, w]
initTrFunct[w_] := Evaluate[%]

FourierTransform[u^{(0,1)}(x,t),x,w]

-k (w^{2}) FourierTransform[u(x,t),x,w]

-\frac{I}{(\sqrt{2 \pi }) w}+(\sqrt{\frac{\pi }{2}}) DiracDelta[w]

PDEtr = D[uTr[w, t], t] == -k w^2 uTr[w, t]
initTr = uTr[w, 0] == initTrFunct[w]

uTr^{(0,1)}(w,t)=-k (w^{2}) uTr(w,t)

uTr(w,0)=-\frac{I}{(\sqrt{2 \pi }) w}+(\sqrt{\frac{\pi }{2}}) DiracDelta[w]

Επίλυση μετασχηματισμένης

sol = DSolve[{PDEtr, initTr}, uTr[w, t], t]

{{uTr(w,t)\to \frac{(E^{-k t (w^{2})}) (-\frac{I}{\sqrt{\pi }}+(\sqrt{\pi }) w DiracDelta[w])}{(\sqrt{2}) w}}}

sol[[1, 1, 2]]

\frac{(E^{-k t (w^{2})}) (-\frac{I}{\sqrt{\pi }}+(\sqrt{\pi }) w DiracDelta[w])}{(\sqrt{2}) w}

sol[[1, 1, 2]]

\frac{(E^{-k t (w^{2})}) (-\frac{I}{\sqrt{\pi }}+(\sqrt{\pi }) w DiracDelta[w])}{(\sqrt{2}) w}

Μετασχηματισμός ημιτόνου Fourier (μετασχηματίζουμε ως προς τα $x\in(0,+\infty)$, όταν η αρχική συνθήκη έχει $u(0,t)=0$).

Η ΜΔΕ

Clear["Global`*"]
PDE = D[u[x, t], t] ==  D[u[x, t], {x, 2}]
f[x_] := DiracDelta[x - a]
init = u[x, 0] == f[x]
bound = u[0, t] == 0

u^{(0,1)}(x,t)=u^{(2,0)}(x,t)

\[u(x,0)=DiracDelta[-a+x]\]

\[u(0,t)=0\]

F[ω_] = FourierSinTransform[f[x], x, ω]
FullSimplify[F[ω], a > 0]

(\sqrt{\frac{2}{\pi }}) HeavisideTheta[a] \sin(a \omega )

(\sqrt{\frac{2}{\pi }}) \sin(a \omega )

Ημιτονικός μετασχηματισμός Fourier της εξίσωσης θερμότητας-διάχυσης.

FourierSinTransform[D[u[x, t], {t, 1}], x, ω] ==  FourierSinTransform[D[u[x, t], {x, 2}], x, ω]

FourierSinTransform[u^{(0,1)}(x,t),x,\omega ]=-\omega (\omega FourierSinTransform[u(x,t),x,\omega ]-(\sqrt{\frac{2}{\pi }}) u(0,t))

Επίλυση της μετασχηματισμένης ΣΔΕ ως προς t όπου έχουμε λάβει
υπόψιν ότι $u(0,t)=0$ και την μετασχηματισμένη εκδοχή της $u(x,0)=δ(x-a)$.

ode = D[
uhat[ω, t], {t, 1}] == -ω^2*
uhat[ω, t];
DSolve[{ode, uhat[ω, 0] == Sqrt[2/π] Sin[a ω]}, uhat[ω, t], t]

v[ω_, t_] = E^(-t ω^2) Sqrt[2/π] Sin[a ω]

(E^{-t ({\omega }^{2})}) (\sqrt{\frac{2}{\pi }}) \sin(a \omega )

Η λύση μας είναι.

u[x_, t_] = InverseFourierSinTransform[v[ω, t], ω, x]

\frac{E^{-\frac{{(a-x)}^{2}}{4 t}}-E^{-\frac{{(a+x)}^{2}}{4 t}}}{2 (\sqrt{\pi }) (\sqrt{t})}

Μετασχηματισμός συνημιτόνου Fourier (μετασχηματίζουμε ως προς τα $x\in(0.+\infty)$), όταν η αρχική συνθήκη έχει $u_x(0,t)=0$)

Η ΜΔΕ

Clear["Global`*"]
PDE = D[u[x, t], t] ==  a^2 D[u[x, t], {x, 2}]
f[x_] = HeavisideTheta[1 - x]
init = u[x, 0] == f[x]
bound = Derivative[1, 0][u][0, t] == 0

u^{(0,1)}(x,t)=(a^{2}) u^{(2,0)}(x,t)

\(HeavisideTheta[1-x]\)

\[u(x,0)=HeavisideTheta[1-x]\]

u^{(1,0)}(0,t)=0

FourierCosTransform[PDE[[1]], x, w]
FourierCosTransform[PDE[[2]], x, w]

FourierCosTransform[u^{(0,1)}(x,t),x,w]

(a^{2}) (-(w^{2}) FourierCosTransform[u(x,t),x,w]-(\sqrt{\frac{2}{\pi }}) u^{(1,0)}(0,t))

Λόγω της $u_x(0,t)=0$ έχουμε:

ODEtr = D[uTr[w, t], t] == -a^2 w^2 uTr[w, t]

uTr^{(0,1)}(w,t)=-(a^{2}) (w^{2}) uTr(w,t)

Μετασχηματίζουμε τη συνοριακή συνθήκη.

FourierCosTransform[f[x], x, w]

(\sqrt{\frac{2}{\pi }}) Sinc[w]

Λύνουμε τη μετασχηματισμένη

DSolve[{ODEtr, uTr[w, 0] == (Sqrt[2/π] Sin[w])/w}, uTr[w, t], t]

{{uTr(w,t)\to \frac{(E^{-(a^{2}) t (w^{2})}) (\sqrt{\frac{2}{\pi }}) \sin(w)}{w}}}

Αντιστρέφουμε τον μετασχηματισμό κι έχουμε την επιθυμητή λύση.

InverseFourierCosTransform[(E^(-a^2 t w^2) Sqrt[2/Pi] Sin[w])/w, w, x]

-\frac{(1+x) (-\left|-1+x\right| Erf[\frac{1+x}{2 (\sqrt{(a^{2}) t})}]+(-1+x) Erf[\frac{\left|-1+x\right|}{2 (\sqrt{(a^{2}) t})}])}{2 \left|-1+x^{2}\right|}

uSol[x_, t_] := -(((1 +   x) (-Abs[-1 + x] Erf[(1 + x)/(2 Sqrt[a^2 t])] + (-1 + x) Erf[ Abs[-1 + x]/(2 Sqrt[a^2 t])]))/(2 Abs[-1 + x^2]))

Σχεδιάζουμε.

a = 1;
Plot3D[uSol[x, t], {x, 0, 10}, {t, 0, 10}, PlotRange -> All,  AxesLabel -> {"x","t"}]